import RightTriangles;

class Finger
extends MovieClip
{
    private var dragging:Boolean;

    public static var symbolName:String = '__Packages.Finger';
    public static var symbolOwner:Function = Finger;
    public static var symbolLink:Boolean = Object.registerClass(symbolName, symbolOwner);

    public function Finger()
    {
        dragging = false;
        draw();
    }
    
    public function draw():Void
    {
        clear();
        
        // square
        lineStyle(0, 0x666666);
        moveTo(-17, -17);
        lineTo(-17, 17);
        lineTo(17, 17);
        lineTo(17, -17);
        lineTo(-17, -17);
        lineStyle();

        var img:MovieClip = createEmptyMovieClip('img', 1);

        img._x = -16;
        img._y = -16;
        img.loadMovie('http://mike.teczno.com/img/right-triangles/finger.jpg');
    }
    
    public function onPress():Void
    {
        dragging = true;
        RightTriangles.onFingerPressed(this);
        startDrag(false, 20, 20, Stage.width-20, Stage.height-20);
    }
    
    public function onDragged():Void
    {
        RightTriangles.onFingerMoved(this);
    }
    
    public function onMouseMove():Void
    {
        if(dragging)
            onDragged();
    }
    
    public function onRelease():Void
    {
        dragging = false;
        RightTriangles.onFingerReleased(this);
        stopDrag();
    }
    
    public function onReleaseOutside():Void
    {
        onRelease();
    }
}